Dan minggu ini sudah keluar versi komersial-nya. Untuk saya yang programmer dengan kantong pas-pasan ini tentu saya mencoba versi Express-nya saja, yang dapat di download dengan gratis. Untuk versi Express anda dapat download sesuai kesukaan anda, berikut daftar yang di ‘express’ kan:

• Microsoft® Visual Web Developer® 2010 Express
• Microsoft® Visual Basic® 2010 Express
• Microsoft® Visual C#® 2010 Express
• Microsoft® Visual C++® 2010

Jika anda ingin lebih serius, terdapat juga versi komersialnya yang tentu lebih professional, dan di versi komersialnya terdapat beberapa edisi, yaitu:

• 2010 Professional
• 2010 Premium
• 2010 Ultimate
• Test Professional 2010

Untuk perbedaan dari 4 versi komersial itu dapat anda lihat disini.

Tentu dengan di barengi dengan .NET Framework 4, kita sebagai programmer berharap, library di dalamnya dalam membantu dalam pekerjaan kita nanti. Saya sudah ngga sabar ingin coba-coba nih, agar nanti bisa cerita-cerita dengan rekan-rekan pembaca blog ini.

Bagaimana menurut anda?

Nah, di artikel ini saya ingin membahas bagaimana mengakses, membuat dan merubah registry sehingga dapat membantu kita membuat satu aplikasi yang applicable dengan menggunakan Visual Basic 2008.

Tentu dengan Visual Basic 2008 ini kita dapat mengakses registry jauh lebih mudah di banding ketika menggunakan Visual Basic 6, karena semua function dan procedure yang di butuhkan sudah ada di framework-nya yang ketika artikel ini di tulis sudah sampai versi 3.5 (versi 4 masih Beta 1).

OK, langsung saja ya perhatikan contoh code di bawah ini:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31

'/-------------daftar konstanta---------------------------
Private Const local_machine = "HKEY_LOCAL_MACHINE\"
Private Const alamat_reg_lengkap As String = "SOFTWARE\ElkanaSoft\ES.NET\"
'/--------------------------------------------------------
Public Sub set_reg_awal()
	Dim reg_key As Object
	'/isi variable registry
	reg_key = My.Computer.Registry.LocalMachine.OpenSubKey(alamat_reg_lengkap, True)
	'/cek apakah nilai registry sudah ada
	If reg_key Is Nothing Then
		'MsgBox("Registry Tidak Ada")
		'/buat registry key standard
		With My.Computer.Registry
			'/buat subkey
			.LocalMachine.CreateSubKey(alamat_reg_lengkap)
			'/buat key default
			.SetValue(local_machine & alamat_reg_lengkap, "Counter", 0, Microsoft.Win32.RegistryValueKind.String)
			.SetValue(local_machine & alamat_reg_lengkap, "Server", "localhost", Microsoft.Win32.RegistryValueKind.String)
			.SetValue(local_machine & alamat_reg_lengkap, "User", "es_mis", Microsoft.Win32.RegistryValueKind.String)
			'/masukan nilai ke public variable
			server_reg = .GetValue(local_machine & alamat_reg_lengkap, "Server", Nothing)
			user_reg = .GetValue(local_machine & alamat_reg_lengkap, "User", Nothing)
		End With
	Else
		With My.Computer.Registry
			'counter_reg = .GetValue(local_machine & alamat_reg_lengkap, "Counter", Nothing)
			server_reg = .GetValue(local_machine & alamat_reg_lengkap, "Server", Nothing)
			user_reg = .GetValue(local_machine & alamat_reg_lengkap, "User", Nothing)
		End With
	End If
End Sub

Pada intinya procedure di atas akan memeriksa apakah nilai registry yang akan kita pakai dalam aplikasi sudah ada, jika belum buat dengan default value yang sudah kita tentukan. Dan berikut penjelasan detailnya:

1. Di baris 2 dan 3, saya buat konstanta alamat registry nya.
2. Buat variable dengan type object.
3. Di baris 8 buka registry key-nya dulu karena kita akan melihat apakah sudah ada alamat registry dalam terdapat dalam kosntanta tersebut.
4. Di baris 10 periksa apakah sudah ada atau belum, jika belum buat registry dengan cara pada baris 17-19. Di baris 17 misalnya, saya membuat registry value dengan jenis String bernama Counter dan saya beri nilai awal 0.
5. Karena saya memerlukan nilai registry tersebut, maka saya masukan ke Public Variable saya di baris 21-22.
6. Tapi jika nilai registry sudah ada langsung ambil nilai registry dengan method GetValue dan masukan langsung ke Public Variable (di baris 26-28).

Nah, cukup mudah kan? Semoga artikel ini bisa sedikit bermanfaat bagi rekan-rekan yang masih belajar Visual Basic 2008, seperti saya ini.

Hal ini juga saya alami, ketika saya mendapat satu pesanan aplikasi yang harus bisa import data dari dBase. Data tersebut harus bisa di’lebur’ ke dalam database utama yang saya buat dengan MySQL. Untuk frontend saya memakai Visual Basic 6.0.

Pertamanya sih bingung juga, setelah cari sana-sini ketemu juga untuk membuka data dBase. Untuk connection string kita masih memakai bantuan konektor Microsoft Jet. Cara penulisan string nya sebagai berikut:

"Provider=Microsoft.Jet.OLEDB.4.0;Data Source=folder_lengkap;Extended Properties=dBASE IV;User ID=Admin;Password=;"

Di Data Source anda bisa ganti dengan path dan nama dBase nya, misalnya file dBase nya adalah contoh.dbf dan berada di folder C:\Data\ maka connection string nya menjadi seperti ini:

"Provider=Microsoft.Jet.OLEDB.4.0;Data Source=C:\Data\;Extended Properties=dBASE IV;User ID=Admin;Password=;"

Buka koneksi string itu dengan object Connection ADODB. Oya, anda bisa tetap memakai ADODB object untuk membukanya. Lalu untuk memakai koneksi di object recordset-nya anda bisa membuka table-nya dengan cara seperti ini:

rs.Open "SELECT * FROM nama_file sehingga dalam contoh ini, anda bisa membuka file contoh.dbf dengan menuliskan SQL statement seperti ini: rs.Open "SELECT * FROM contoh.dbf.

Nah, proses selanjutnya anda bisa mengelola nya seperti biasa dan untuk lebih jelasnya, rekan-rekan bisa melihat contoh dari aplikasi saya:

Dim conn_mpm As ADODB.Connection
Dim rs_data As New ADODB.Recordset
Dim con_string_mpm As String
Dim folder_data As String
Dim nama_file As String
Dim str_sql As String
'/berikan default nama file dan path db
folder_data = "C:\Data\"
nama_file = "contoh.dbf"
'/set connection string
con_string_mpm = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & folder_data & ";Extended Properties=dBASE IV;User ID=Admin;Password=;"
'/buka koneksi
Set conn_mpm = New ADODB.Connection
With conn_mpm
    .ConnectionString = con_string_mpm
    .CursorLocation = adUseClient
    .Open
End With
'/string sql
str_sql = "SELECT * FROM " & nama_file
With rs_data
    .CursorLocation = adUseClient
    .Open str_sql, conn_mpm, adOpenStatic, adLockReadOnly
    .Requery
    If .RecordCount <= 0 Then
        MsgBox "Tidak ada data di dalam file!", vbExclamation, "Kosong"
    Else
        masukan field ke control form anda.
    End If
End With
'/hapus memory
Set rs_data = Nothing

Semoga artikel ini bisa sedikit bermanfaat.

Seperti di artikel sebelumnya, dalam kasus ini misalnya saya mempunyai sebuah tabel dengan isi field: no_urut, nama_karyawan, usia dan saya akan menuliskan 2 cara untuk melakukan hal itu.

Cara pertama:

1. Membuat object recordset dulu dengan baris Dim rs As New ADODB.Recordset
2. Membuka data di SQL server secara spesifik (gunakan perintah WHERE).
3. Berikut baris sintaks secara lengkap:

   With rs
       .CursorLocation = adUseClient
       .Open "SELECT * FROM tbl_karyawan WHERE no_urut = 1, Conn, adOpenKeyset, adLockOptimistic
       .Requery
       .Fields(nama_karyawan) = "Edi Susanto"
       .Fields(usia) = 30
       .Update
   End With

Cara kedua:

1. Menggunakan obyek koneksi.
2. Caranya sebagai berikut:

   Dim strUpdate As String
   strUpdate = "UPDATE tbl_karyawan SET nama_karyawan='Udin', usia=16 WHERE no_urut=1"
   Conn.Execute strUpdate

3. Jangan lupa gunakan perintah WHERE, karena kalo anda tidak mencantumkan pengkondisian tersebut semua data anda akan di update.

Semoga artikel ini bisa menjadi pengetahuan basic bagi para rekan-rekan yang ingin membuat aplikasi database.

Dalam kasus ini misalnya saya mempunyai sebuah tabel dengan isi field: no_urut, nama_karyawan, usia.

Yang Pertama, melalui obyek recordset.

1. Buat obyek recordset dahulu melalui variable. Tentu rekan-rekan sudah mengetahui hal ini, yaitu Dim rs As New ADODB.Recordset
2. Untuk menyimpan sebaris data kedalam tabel tersebut adalah sebagai berikut:

   rs.Open "select * from tbl_karyawan", Conn, adOpenDynamic, adLockOptimistic
   rs.AddNew
   rs.Fields("nama_karyawan") = "Udin"
   rs.Fields("usia") = 16
   If MsgBox("Data akan disimpan?", vbYesNo) = vbYes Then
        rs.Update
   Else
        rs.CancelUpdate
   End If
   rs.Close

3. Data anda sudah tersimpan.

Yang Kedua, melalui syntax SQL

1. Kita akan memakai obyek koneksi anda ke database, artikel lengkap tentang obyek koneksi ke database dapat anda baca di artikel ini. Misalnya obyek koneksi kita namai dengan Conn.
2. Scriptnya secara garis besar seperti ini:

   Dim strUpdate As String
   strInsert = "INSERT INTO tbl_karyawan(nama_karyawan, usia) VALUES ('Udin', 16)"
   Conn.Execute strInsert

3. Data anda sudah tersimpan.

Tentu kedua metode di atas mempunyai kelemahan dan kelebihannya sendiri. Kalau saya pribadi suka memakai cara yang kedua. Tapi semua keputusan di tangan anda. Selamat mencoba.

Nah, function inilah yang akan kita gunakan untuk mengatur script kita kali ini. Tertarik? Ikuti langkah berikut:

1. Buka notepad anda, dengan klik Start -> Run, ketik notepad lalu tekan Enter (rekan-rekan boleh menggunakan cara lain untuk membukanya).
2. Copy – Paste code di bawah ini ke dalam Notepad.

   Dim my_reg  
   atur_regedit()  
   Sub atur_regedit()  
   Set my_reg=WScript.CreateObject("wscript.shell")  
   describe="Ketik 0 atau 1 : " & VbCrLf &_  
                "[0] -> Buka Regedit." & VbCrLf &_  
                "[1] -> Blok Regedit."  
    
   question=InputBox(describe, "Atur Regedit",0)  
   my_reg.RegWrite "HKCU\Software\Microsoft\Windows\CurrentVersion" &_  
                           "\Policies\System\DisableRegistryTools",question,"REG_DWORD"  
    
   If question=1 Then  
      MsgBox "Registry Editor di blok.",VbInformation, "Blok"  
   Else  
      If question=0 Then  
         Msgbox "Registry Editor di buka.",VbInformation, "Buka"  
         my_reg.RegDelete "HKCU\Software\Microsoft\Windows\CurrentVersion" &_  
                                   "\Policies\System\DisableRegistryTools"  
      Else  
         Msgbox "Masukan angka 1 dan 0 saja!",VbInformation, "Salah input"  
         atur_regedit()  
      End If  
   End If  
   End Sub

3. Save code itu dengan klik menu File -> Save, beri nama atur regedit.vbs (bisa anda beri nama anda sendiri tapi ekstensi harus .vbs), pilih All Files di pilihan Save as type lalu klik tombol Save. Jangan lupa arahkan ke folder yang anda ingat.
   
4. Masuk ke folder dimana anda menyimpan script tersebut, lalu klik ganda file script tadi, kalau dalam kasus saya, saya simpan dengan nama atur regedit.vbs.
   
5. Lalu akan muncul aplikasi hasil interpreter script yang barusan kita buat tadi.
   
6. Nah, untuk membuka anda tinggal isi dengan angka 0 lalu klik tombol OK.
   
7. Dan jika anda memberi angka 1 maka Regedit akan terblok.
   
8. Untuk memastikan apakah kita berhasil memblok Registry Editor, buka aja melalui Start -> Run, ketik regedit lalu tekan Enter, jika anda mendapat pesan kesalahan berarti script tersebut sudah berhasil.
   

Selamat mencoba dan semoga bermanfaat bagi rekan-rekan.

Ada beberapa event yang membuat saya menggunakan pemeriksaan ini, biasanya adalah dalam event Save dan baca record. Jika saya akan save, sebuah record dengan unique id, saya akan memeriksa apakah unique id ini sudah ada di database atau belum, jika sudah ada tentu saya akan ‘melempar’ hasilnya menjadi sebuah message box dan jika belum ada, akan saya teruskan procedure penyimpanannya. Untuk event baca record juga begitu, jika record dengan unique id yang saya maksud tidak ada maka saya akan memberitahu user dan jika ada maka procedure baca akan di teruskan.

Dan saya selalu membuat satu Public Function untuk ini, jadi saya tinggal memanggilnya dimana pun saya berada di project tersebut, function tersebut saya taruh di satu module. Function ini bertipe Boolean, jadi dalam penggunaannya nanti akan memudahkan saya, tinggal saya mengecek apakah hasilnya true atau false. Dan berikut function yang saya namakan Function apakah ada.

Public Function apakah_ada(ByVal sTable As String, ByVal sField As String, ByVal sStr As String, Optional isNum As Boolean) As Boolean
Dim rs_apa_ada As New ADODB.Recordset
On Error GoTo apakah_ada_Error
With rs_apa_ada
    .CursorLocation = adUseClient
If isNum = True Then
    .Open "SELECT * FROM " & sTable & " WHERE " & sField & " = " & sStr, myconn, adOpenStatic, adLockReadOnly
Else
    .Open "SELECT * FROM " & sTable & " WHERE " & sField & " = '" & sStr & "'", myconn, adOpenStatic, adLockReadOnly
End If
If .RecordCount <= 0 Then
    apakah_ada = False
Else
    apakah_ada = True
End If
.Close
End With
Set rs_apa_ada = Nothing
 
'___________________________________________________________
On Error GoTo 0
Exit Function
 
apakah_ada_Error:
    MsgBox "Ada Kesalahan ! " & vbCrLf & "Nomor Kesalahan : " & Err.Number & vbCrLf & "Deskripsi : " & Err.Description & vbCrLf & "Di prosedur apakah_ada dalam modul mdlfungsi_aplikasi"
End Function

Misal saya akan memeriksa apakah kode barang yang akan saya masukan sudah ada, maka untuk penggunaan function ini adalah sebagai berikut:

'/cek apakah ada ada kode barang yang dimasukkan
If apakah_ada("tbl_data_induk_barang", "kode_barang", kode_barang, False) = False Then MsgBox "Kode barang: " & kode_barang & " tidak ditemukan!", vbExclamation, "Tidak Ditemukan": Exit Sub

Semoga sedikit bermanfaat…

Logika dari function ini adalah mengambil lebar layar dikurangi dengan lebar form nya lalu di bagi 2. Tentu hal akan membuat sudut kiri form akan di letakan dimana ‘sisa’ space kosong sebelah kiri dan kanan form akan memiliki lebar yang sama. Untuk tinggi form juga akan di gerakan dengan perhitungan yang sama.

Nah, berikut adalah function bentuk jadinya.

Sub TengahkanPersis(f As Form)
' Tengahkan form yang anda maksud
f.Move (Screen.Width - f.Width) \ 2, ((Screen.Height - (f.Height)) \ 2)
End Sub

Untuk menggunakan form itu, letakan di prosedur Form_Load. Jadi begitu form terbuka, function TengahkanPersis akan di panggil dan akan meletakan form anda di tengah-tengah layar. Berikut contoh pemanggilan function ini.

Private Sub Form_Load()
'/tengahkan form
TengahkanPersis Me
'/baris berikut isi dengan function yang lain.
End Sub

Semoga artikel ini bermanfaat.

Dan saya tahu setiap programmer mempunyai caranya sendiri-sendiri untuk trace kesalahan tersebut. Kalau saya pada intinya, setiap string SQL saya selalu letakan di sebuah variable dan variable inilah nantinya yang saya manipulasi melalui Immediate Window-nya Visual Basic.

Misalnya saya akan membuka data yang saya inginkan melalui satu procedure ini:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27

Private Sub refresh_grid()
Dim rs_grid As New ADODB.Recordset
Dim kode_pos As String
Dim str_open As String
'/set kode bengkel
kode_pos = Trim(lbl_kode_pos.Caption)
'/set string
str_open = "SELECT spos.pos_id, spos.kode_barang, mb.nama_barang, mb.satuan, spos.jumlah, spos.harga_jual, (spos.jumlah*spos.harga_jual) AS sub_total "
str_open = str_open & "FROM tbl_sub_pos AS spos INNER JOIN tbl_data_induk_barang AS mb ON spos.kode_barang=mb.kode_barang "
str_open = str_open & "WHERE spos.kode_pos='" & kode_pos & "'"
'/buka recordset
With rs_grid
    .CursorLocation = adUseClient
    .Open str_open, myconn, adOpenStatic, adLockReadOnly
    .Requery
End With
'/isi grid
With grid_pos
    .DataSource = rs_grid
    .ReBind
    .Refresh
End With
'/jumlahkan sub total
jumlahkan_sub_total
'/hapus memory
Set rs_grid = Nothing
End Sub

Dan jika terjadi kesalahan langkah berikut yang saya ambil:

1. Saya sekali lagi selalu meletakan string SQL saya ke sebuah variable dan tidak langsung di buka di dalam blok pembukaan recordset. Misalnya: rs_grid.Open "SELECT mb.kode_barang FROM tbl_master_barang". Karena jika terjadi kesalahan akan susah melacaknya di Immediate Window.
2. Jika ketika anda me-run coding anda dan anda di beritahukan ada kesalahan dari SQL anda, maka klik tombol Debug.
   
3. Maka anda akan ‘dikembalikan’ ke layar Visual Basic anda dan Visual basic akan menunjukkan letak baris kesalahan,
   
   lalu secara otomatis Immediate Window akan muncul, lalu di Immediate Window ketikkan ?nama_variable_sql. Jadi misalnya string SQL saya tampung di variable str_open, maka saya ketik ?str_open untuk melihat isi dari variable tersebut.
   
4. Dan langkah berikutnya yang saya ambil adalah meng-copy seluruh baris SQL tersebut dan saya paste ke SQL editor kesayangan saya.
   
5. DI MySQL Query Browser saya akan terbantu karena Query Browser akan membedakan antara string, sintaks dasar, dll sehingga saya jauh lebih terbantu untuk menemukan kesalahan SQL saya. Dan jika kesalahan sudah saya temukan, maka akan saya benahi di Visual Basic saya.

Nah, kira-kira apa langkah yang biasa anda lakukan jika terjadi kesalahan di baris SQL anda?

Seperti ketika saya akan  membuat koneksi ke MySQL dengan connector ODBC versi 5.1 ini, saya harus menuliskan:

str_conn = "DRIVER={MySQL ODBC 5.1 Driver};SERVER=" & db_server & ";DATABASE=" & db_name & ";UID=" & db_user & ";PWD=" & db_pass & ";PORT=" & db_port & ";OPTION=3"

Dan ketika anda membuatnya dengan VB.NET misalnya string itu harus di ubah lagi karena disarankan tidak memakai ODBC lagi di lingungan .NET programming. Atau singkat kata setiap ada perubahan dengan connector nya atau database server tentu akan berubah pula connection string-nya.

Sering kali saya bingung, harus kemana dulu mencari-nya, melihat dokumen dari database server atau connector tentu menjadi hal yang baik, tetapi anda harus melihat satu-persatu atau mencari-nya dulu secara teliti.

Saya sarankan jika anda mengalami hal yang sama, kunjungi saja situs satu ini. Seperti ketika saya mencari connection string untuk MySQL, saya dengan mudah bisa menemukannya.

Semoga membantu.